Cython 优化根查找 API#

以下根查找器的底层C函数可以通过Cython直接访问：

根查找函数的 Cython API 类似，只是没有 disp 参数。使用 cimport 从 scipy.optimize.cython_optimize 导入根查找函数。:

from scipy.optimize.cython_optimize cimport bisect, ridder, brentq, brenth

回调签名#

cython_optimize 中的 zeros 函数期望一个回调函数，该回调函数的第一个参数为标量独立变量的双精度类型，第二个参数为用户定义的 struct，包含任何额外的参数。:

double (*callback_type)(double, void*) noexcept

示例

使用 cython_optimize 需要 Cython 来编写编译成 C 的回调函数。有关编译 Cython 的更多信息，请参阅 Cython 文档。

这些是基本步骤：

  1. 创建一个 Cython .pyx 文件，例如：myexample.pyx。

  2. 从 cython_optimize 导入所需的根查找器。

  3. 编写回调函数，并调用选定的根查找函数，传递回调函数、任何额外参数和其他求解器参数。:

    from scipy.optimize.cython_optimize cimport brentq

# import math from Cython
from libc cimport math

myargs = {'C0': 1.0, 'C1': 0.7}  # a dictionary of extra arguments
XLO, XHI = 0.5, 1.0  # lower and upper search boundaries
XTOL, RTOL, MITR = 1e-3, 1e-3, 10  # other solver parameters

# user-defined struct for extra parameters
ctypedef struct test_params:
    double C0
    double C1

# user-defined callback
cdef double f(double x, void *args) noexcept:
    cdef test_params *myargs = <test_params *> args
    return myargs.C0 - math.exp(-(x - myargs.C1))


# Cython wrapper function
cdef double brentq_wrapper_example(dict args, double xa, double xb,
                                   double xtol, double rtol, int mitr):
    # Cython automatically casts dictionary to struct
    cdef test_params myargs = args
    return brentq(
        f, xa, xb, <test_params *> &myargs, xtol, rtol, mitr, NULL)


# Python function
def brentq_example(args=myargs, xa=XLO, xb=XHI, xtol=XTOL, rtol=RTOL,
                   mitr=MITR):
    '''Calls Cython wrapper from Python.'''
    return brentq_wrapper_example(args, xa, xb, xtol, rtol, mitr)

  4. 如果你想从Python中调用你的函数，创建一个Cython包装器，以及一个调用该包装器的Python函数，或者使用 cpdef。然后，在Python中，你可以导入并运行示例。

    from myexample import brentq_example

x = brentq_example()
# 0.6999942848231314

  5. 如果你需要导出任何Cython函数，请创建一个Cython .pxd 文件。

Full Output#

cython_optimize 中的函数也可以将求解器的完整输出复制到一个作为其最后一个参数传递的 C struct 中。如果你不需要完整输出，只需传递 NULL。完整输出 struct 的类型必须是 zeros_full_output，该类型在 scipy.optimize.cython_optimize 中定义，包含以下字段：

  • int funcalls: 函数调用次数

  • int iterations: 迭代次数

  • int error_num: 错误编号

  • double root: 函数的根

根被 cython_optimize 复制到完整的输出 struct 中。错误代码 -1 表示符号错误，-2 表示收敛错误，0 表示求解器收敛。继续上一个例子:

from scipy.optimize.cython_optimize cimport zeros_full_output


# cython brentq solver with full output
cdef zeros_full_output brentq_full_output_wrapper_example(
        dict args, double xa, double xb, double xtol, double rtol,
        int mitr):
    cdef test_params myargs = args
    cdef zeros_full_output my_full_output
    # use my_full_output instead of NULL
    brentq(f, xa, xb, &myargs, xtol, rtol, mitr, &my_full_output)
    return my_full_output


# Python function
def brent_full_output_example(args=myargs, xa=XLO, xb=XHI, xtol=XTOL,
                              rtol=RTOL, mitr=MITR):
    '''Returns full output'''
    return brentq_full_output_wrapper_example(args, xa, xb, xtol, rtol,
                                              mitr)

result = brent_full_output_example()
# {'error_num': 0,
#  'funcalls': 6,
#  'iterations': 5,
#  'root': 0.6999942848231314}
On this page