自定义C++和CUDA扩展
创建日期：2018年4月26日 | 最后更新：2024年7月22日 | 最后验证：2024年11月5日
警告
本教程自 PyTorch 2.4 起已弃用。请参阅 PyTorch 自定义操作符 获取关于使用自定义 C++/CUDA 扩展扩展 PyTorch 的最新指南。
PyTorch 提供了大量与神经网络、任意张量代数、数据处理等相关的操作。然而，您可能仍然需要更定制的操作。例如，您可能希望使用在论文中发现的新颖激活函数，或者实现作为您研究的一部分开发的操作。
在PyTorch中集成这种自定义操作的最简单方法是按照这里的概述，通过扩展Function和Module在Python中编写它。这为您提供了自动微分的全部功能（无需编写导数函数）以及Python通常的表达能力。然而，有时您的操作可能更适合在C++中实现。例如，您的代码可能需要非常快，因为它在您的模型中非常频繁地被调用，或者即使调用次数很少也非常昂贵。另一个可能的原因是它依赖于或与其他C或C++库交互。为了解决这些情况，PyTorch提供了一种非常简单的编写自定义C++扩展的方法。
C++扩展是我们开发的一种机制，允许用户（您）创建源外定义的PyTorch操作符，即与PyTorch后端分离。这种方法与原生PyTorch操作的实现方式不同。C++扩展旨在为您节省与将操作与PyTorch后端集成相关的大量样板代码，同时为您的基于PyTorch的项目提供高度的灵活性。然而，一旦您将您的操作定义为C++扩展，将其转换为原生PyTorch函数主要是一个代码组织问题，如果您决定将您的操作贡献给上游，您可以在事后处理。
动机与示例
本说明的其余部分将通过一个实际的例子来介绍如何编写和使用C++（和CUDA）扩展。如果你正在被追赶，或者有人威胁你如果今天不完成那个操作就会被解雇，你可以跳过这一部分，直接进入下一节的实现细节。
假设你提出了一种新的循环单元，发现它比现有技术具有更优越的特性。这个循环单元类似于LSTM，但不同之处在于它缺少一个遗忘门，并使用指数线性单元（ELU）作为其内部激活函数。由于这个单元永远不会忘记，我们将其称为LLTM，即长长期记忆单元。
LLTMs与普通LSTMs的两种不同之处非常重要，以至于我们无法为我们的目的配置PyTorch的LSTMCell，因此我们必须创建一个自定义单元。第一个也是最简单的方法——在所有情况下可能都是一个好的第一步——是在纯PyTorch中使用Python实现我们所需的功能。为此，我们需要子类化torch.nn.Module并实现LLTM的前向传递。这将看起来像这样：
class LLTM(torch.nn.Module):
def __init__(self, input_features, state_size):
super(LLTM, self).__init__()
self.input_features = input_features
self.state_size = state_size
# 3 * state_size for input gate, output gate and candidate cell gate.
# input_features + state_size because we will multiply with [input, h].
self.weights = torch.nn.Parameter(
torch.empty(3 * state_size, input_features + state_size))
self.bias = torch.nn.Parameter(torch.empty(3 * state_size))
self.reset_parameters()
def reset_parameters(self):
stdv = 1.0 / math.sqrt(self.state_size)
for weight in self.parameters():
weight.data.uniform_(-stdv, +stdv)
def forward(self, input, state):
old_h, old_cell = state
X = torch.cat([old_h, input], dim=1)
# Compute the input, output and candidate cell gates with one MM.
gate_weights = F.linear(X, self.weights, self.bias)
# Split the combined gate weight matrix into its components.
gates = gate_weights.chunk(3, dim=1)
input_gate = torch.sigmoid(gates[0])
output_gate = torch.sigmoid(gates[1])
# Here we use an ELU instead of the usual tanh.
candidate_cell = F.elu(gates[2])
# Compute the new cell state.
new_cell = old_cell + candidate_cell * input_gate
# Compute the new hidden state and output.
new_h = torch.tanh(new_cell) * output_gate
return new_h, new_cell
然后我们可以按预期使用：
import torch
X = torch.randn(batch_size, input_features)
h = torch.randn(batch_size, state_size)
C = torch.randn(batch_size, state_size)
rnn = LLTM(input_features, state_size)
new_h, new_C = rnn(X, (h, C))
自然，如果可能且合理，你应该使用这种方法来扩展PyTorch。由于PyTorch对其操作在CPU和GPU上有着高度优化的实现，这些实现由NVIDIA cuDNN、Intel MKL或NNPACK等库提供支持，因此像上面这样的PyTorch代码通常已经足够快。然而，我们也可以看到，在某些情况下，仍有进一步性能提升的空间。最明显的原因是PyTorch对你正在实现的算法一无所知。它只知道你用来组成算法的各个操作。因此，PyTorch必须逐个执行你的操作。由于每个操作实现（或内核）的调用可能涉及CUDA内核的启动，这会有一定的开销，这种开销在许多函数调用中可能会变得显著。此外，运行我们代码的Python解释器本身也可能减慢我们的程序。
因此，加快速度的一个明确方法是用C++（或CUDA）重写部分代码，并融合特定的操作组。融合意味着将许多函数的实现合并为一个单一的函数，这样可以减少内核启动次数，并且由于对数据全局流的可见性增加，我们可以进行其他优化。
让我们看看如何使用C++扩展来实现LLTM的融合版本。我们将首先使用支持PyTorch后端的ATen库以纯C++编写它，并看看它如何轻松地让我们将Python代码转换为C++代码。然后，我们将通过将模型的部分移动到CUDA内核来进一步加速，以利用GPU提供的大规模并行性。
编写C++扩展
C++扩展有两种形式：它们可以通过setuptools“提前”构建，或者通过torch.utils.cpp_extension.load()“即时”构建。我们将从第一种方法开始，稍后再讨论后者。
使用setuptools构建
对于“提前”模式，我们通过编写一个使用setuptools编译C++代码的setup.py脚本来构建我们的C++扩展。对于LLTM，它看起来像这样简单：
from setuptools import setup, Extension
from torch.utils import cpp_extension
setup(name='lltm_cpp',
ext_modules=[cpp_extension.CppExtension('lltm_cpp', ['lltm.cpp'])],
cmdclass={'build_ext': cpp_extension.BuildExtension})
在这段代码中，CppExtension 是一个方便的包装器，围绕
setuptools.Extension，它传递了正确的包含路径并将
扩展的语言设置为 C++。等效的原生 setuptools
代码将简单地是：
Extension(
name='lltm_cpp',
sources=['lltm.cpp'],
include_dirs=cpp_extension.include_paths(),
language='c++')
BuildExtension 执行了许多必需的配置步骤和检查，并且在混合 C++/CUDA 扩展的情况下管理混合编译。这就是我们现在需要了解的关于构建 C++ 扩展的全部内容！现在让我们来看看我们的 C++ 扩展的实现，它位于 lltm.cpp 中。
编写C++ Op
让我们开始在C++中实现LLTM！在反向传播中我们需要的一个函数是sigmoid的导数。这段代码足够小，可以讨论我们在编写C++扩展时可用的整体环境：
#include <torch/extension.h>
#include <iostream>
torch::Tensor d_sigmoid(torch::Tensor z) {
auto s = torch::sigmoid(z);
return (1 - s) * s;
}
ATen库是我们用于张量计算的主要API，
pybind11，这是我们为C++代码创建Python绑定的方式，
管理ATen和pybind11之间交互细节的头文件。
d_sigmoid() 的实现展示了如何使用 ATen API。PyTorch 的张量和变量接口是从 ATen 库自动生成的，因此我们可以或多或少地将我们的 Python 实现 1:1 转换为 C++。我们所有计算的主要数据类型将是 torch::Tensor。它的完整 API 可以在这里查看。还要注意，我们可以包含
请注意，CUDA-11.5 nvcc 在 Windows 上解析 torch/extension.h 时会出现内部编译器错误。 要解决此问题，请将 Python 绑定逻辑移动到纯 C++ 文件中。 示例用法：
#include <ATen/ATen.h>
at::Tensor SigmoidAlphaBlendForwardCuda(....)
而不是：
#include <torch/extension.h>
torch::Tensor SigmoidAlphaBlendForwardCuda(...)
当前开放的nvcc bug问题这里。 完整的解决方法代码示例这里。
前向传播
接下来我们可以将整个前向传播移植到C++：
#include <vector>
std::vector<at::Tensor> lltm_forward(
torch::Tensor input,
torch::Tensor weights,
torch::Tensor bias,
torch::Tensor old_h,
torch::Tensor old_cell) {
auto X = torch::cat({old_h, input}, /*dim=*/1);
auto gate_weights = torch::addmm(bias, X, weights.transpose(0, 1));
auto gates = gate_weights.chunk(3, /*dim=*/1);
auto input_gate = torch::sigmoid(gates[0]);
auto output_gate = torch::sigmoid(gates[1]);
auto candidate_cell = torch::elu(gates[2], /*alpha=*/1.0);
auto new_cell = old_cell + candidate_cell * input_gate;
auto new_h = torch::tanh(new_cell) * output_gate;
return {new_h,
new_cell,
input_gate,
output_gate,
candidate_cell,
X,
gate_weights};
}
反向传播
C++扩展API目前没有提供自动生成反向函数的方法。因此，我们还需要实现LLTM的反向传播，它计算损失相对于前向传播每个输入的导数。最终，我们将把前向和反向函数放入torch.autograd.Function中，以创建一个良好的Python绑定。反向函数稍微复杂一些，所以我们不会深入代码（如果你感兴趣，Alex Graves的论文是了解更多信息的好读物）：
// tanh'(z) = 1 - tanh^2(z)
torch::Tensor d_tanh(torch::Tensor z) {
return 1 - z.tanh().pow(2);
}
// elu'(z) = relu'(z) + { alpha * exp(z) if (alpha * (exp(z) - 1)) < 0, else 0}
torch::Tensor d_elu(torch::Tensor z, torch::Scalar alpha = 1.0) {
auto e = z.exp();
auto mask = (alpha * (e - 1)) < 0;
return (z > 0).type_as(z) + mask.type_as(z) * (alpha * e);
}
std::vector<torch::Tensor> lltm_backward(
torch::Tensor grad_h,
torch::Tensor grad_cell,
torch::Tensor new_cell,
torch::Tensor input_gate,
torch::Tensor output_gate,
torch::Tensor candidate_cell,
torch::Tensor X,
torch::Tensor gate_weights,
torch::Tensor weights) {
auto d_output_gate = torch::tanh(new_cell) * grad_h;
auto d_tanh_new_cell = output_gate * grad_h;
auto d_new_cell = d_tanh(new_cell) * d_tanh_new_cell + grad_cell;
auto d_old_cell = d_new_cell;
auto d_candidate_cell = input_gate * d_new_cell;
auto d_input_gate = candidate_cell * d_new_cell;
auto gates = gate_weights.chunk(3, /*dim=*/1);
d_input_gate *= d_sigmoid(gates[0]);
d_output_gate *= d_sigmoid(gates[1]);
d_candidate_cell *= d_elu(gates[2]);
auto d_gates =
torch::cat({d_input_gate, d_output_gate, d_candidate_cell}, /*dim=*/1);
auto d_weights = d_gates.t().mm(X);
auto d_bias = d_gates.sum(/*dim=*/0, /*keepdim=*/true);
auto d_X = d_gates.mm(weights);
const auto state_size = grad_h.size(1);
auto d_old_h = d_X.slice(/*dim=*/1, 0, state_size);
auto d_input = d_X.slice(/*dim=*/1, state_size);
return {d_old_h, d_input, d_weights, d_bias, d_old_cell};
}
绑定到Python
一旦你用C++和ATen编写了你的操作，你可以使用pybind11以非常简单的方式将你的C++函数或类绑定到Python中。关于PyTorch C++扩展的这部分问题或疑问，大部分都可以通过pybind11文档来解决。
对于我们的扩展，必要的绑定代码仅跨越四行：
PYBIND11_MODULE(TORCH_EXTENSION_NAME, m) {
m.def("forward", &lltm_forward, "LLTM forward");
m.def("backward", &lltm_backward, "LLTM backward");
}
这里需要注意的一点是宏TORCH_EXTENSION_NAME。torch扩展构建会将其定义为你为扩展在setup.py脚本中给出的名称。在这种情况下，TORCH_EXTENSION_NAME的值将是“lltm_cpp”。这是为了避免在两个地方（构建脚本和你的C++代码）维护扩展名称，因为两者之间的不匹配可能会导致难以追踪的问题。
使用您的扩展
我们现在准备在PyTorch中导入我们的扩展。此时，你的目录结构可能看起来像这样：
pytorch/
lltm-extension/
lltm.cpp
setup.py
现在，运行 python setup.py install 来构建并安装你的扩展。这应该看起来像这样：
running install
running bdist_egg
running egg_info
creating lltm_cpp.egg-info
writing lltm_cpp.egg-info/PKG-INFO
writing dependency_links to lltm_cpp.egg-info/dependency_links.txt
writing top-level names to lltm_cpp.egg-info/top_level.txt
writing manifest file 'lltm_cpp.egg-info/SOURCES.txt'
reading manifest file 'lltm_cpp.egg-info/SOURCES.txt'
writing manifest file 'lltm_cpp.egg-info/SOURCES.txt'
installing library code to build/bdist.linux-x86_64/egg
running install_lib
running build_ext
building 'lltm_cpp' extension
creating build
creating build/temp.linux-x86_64-3.7
gcc -pthread -B ~/local/miniconda/compiler_compat -Wl,--sysroot=/ -Wsign-compare -DNDEBUG -g -fwrapv -O3 -Wall -Wstrict-prototypes -fPIC -I~/local/miniconda/lib/python3.7/site-packages/torch/include -I~/local/miniconda/lib/python3.7/site-packages/torch/include/torch/csrc/api/include -I~/local/miniconda/lib/python3.7/site-packages/torch/include/TH -I~/local/miniconda/lib/python3.7/site-packages/torch/include/THC -I~/local/miniconda/include/python3.7m -c lltm.cpp -o build/temp.linux-x86_64-3.7/lltm.o -DTORCH_API_INCLUDE_EXTENSION_H -DTORCH_EXTENSION_NAME=lltm_cpp -D_GLIBCXX_USE_CXX11_ABI=1 -std=c++11
cc1plus: warning: command line option ‘-Wstrict-prototypes’ is valid for C/ObjC but not for C++
creating build/lib.linux-x86_64-3.7
g++ -pthread -shared -B ~/local/miniconda/compiler_compat -L~/local/miniconda/lib -Wl,-rpath=~/local/miniconda/lib -Wl,--no-as-needed -Wl,--sysroot=/ build/temp.linux-x86_64-3.7/lltm.o -o build/lib.linux-x86_64-3.7/lltm_cpp.cpython-37m-x86_64-linux-gnu.so
creating build/bdist.linux-x86_64
creating build/bdist.linux-x86_64/egg
copying build/lib.linux-x86_64-3.7/lltm_cpp.cpython-37m-x86_64-linux-gnu.so -> build/bdist.linux-x86_64/egg
creating stub loader for lltm_cpp.cpython-37m-x86_64-linux-gnu.so
byte-compiling build/bdist.linux-x86_64/egg/lltm_cpp.py to lltm_cpp.cpython-37.pyc
creating build/bdist.linux-x86_64/egg/EGG-INFO
copying lltm_cpp.egg-info/PKG-INFO -> build/bdist.linux-x86_64/egg/EGG-INFO
copying lltm_cpp.egg-info/SOURCES.txt -> build/bdist.linux-x86_64/egg/EGG-INFO
copying lltm_cpp.egg-info/dependency_links.txt -> build/bdist.linux-x86_64/egg/EGG-INFO
copying lltm_cpp.egg-info/top_level.txt -> build/bdist.linux-x86_64/egg/EGG-INFO
writing build/bdist.linux-x86_64/egg/EGG-INFO/native_libs.txt
zip_safe flag not set; analyzing archive contents...
__pycache__.lltm_cpp.cpython-37: module references __file__
creating 'dist/lltm_cpp-0.0.0-py3.7-linux-x86_64.egg' and adding 'build/bdist.linux-x86_64/egg' to it
removing 'build/bdist.linux-x86_64/egg' (and everything under it)
Processing lltm_cpp-0.0.0-py3.7-linux-x86_64.egg
removing '~/local/miniconda/lib/python3.7/site-packages/lltm_cpp-0.0.0-py3.7-linux-x86_64.egg' (and everything under it)
creating ~/local/miniconda/lib/python3.7/site-packages/lltm_cpp-0.0.0-py3.7-linux-x86_64.egg
Extracting lltm_cpp-0.0.0-py3.7-linux-x86_64.egg to ~/local/miniconda/lib/python3.7/site-packages
lltm-cpp 0.0.0 is already the active version in easy-install.pth
Installed ~/local/miniconda/lib/python3.7/site-packages/lltm_cpp-0.0.0-py3.7-linux-x86_64.egg
Processing dependencies for lltm-cpp==0.0.0
Finished processing dependencies for lltm-cpp==0.0.0
关于编译器的一个小提示：由于ABI版本问题，用于构建C++扩展的编译器必须与构建PyTorch的编译器ABI兼容。实际上，这意味着在Linux上你必须使用GCC 4.9及以上版本。对于Ubuntu 16.04和其他较新的Linux发行版，这应该已经是默认的编译器。在MacOS上，你必须使用clang（它没有任何ABI版本问题）。在最坏的情况下，你可以用你的编译器从源代码构建PyTorch，然后用相同的编译器构建扩展。
一旦你的扩展构建完成，你可以简单地使用你在setup.py脚本中指定的名称在Python中导入它。只需确保首先import torch，因为这将解析动态链接器必须看到的一些符号：
In [1]: import torch
In [2]: import lltm_cpp
In [3]: lltm_cpp.forward
Out[3]: <function lltm.PyCapsule.forward>
如果我们调用help()函数或模块，我们可以看到它的签名与我们的C++代码匹配：
In[4] help(lltm_cpp.forward)
forward(...) method of builtins.PyCapsule instance
forward(arg0: torch::Tensor, arg1: torch::Tensor, arg2: torch::Tensor, arg3: torch::Tensor, arg4: torch::Tensor) -> List[torch::Tensor]
LLTM forward
既然我们现在能够从Python调用我们的C++函数，我们可以用torch.autograd.Function和torch.nn.Module来包装它们，使它们成为PyTorch的一等公民：
import math
import torch
# Our module!
import lltm_cpp
class LLTMFunction(torch.autograd.Function):
@staticmethod
def forward(ctx, input, weights, bias, old_h, old_cell):
outputs = lltm_cpp.forward(input, weights, bias, old_h, old_cell)
new_h, new_cell = outputs[:2]
variables = outputs[1:] + [weights]
ctx.save_for_backward(*variables)
return new_h, new_cell
@staticmethod
def backward(ctx, grad_h, grad_cell):
outputs = lltm_cpp.backward(
grad_h.contiguous(), grad_cell.contiguous(), *ctx.saved_tensors)
d_old_h, d_input, d_weights, d_bias, d_old_cell = outputs
return d_input, d_weights, d_bias, d_old_h, d_old_cell
class LLTM(torch.nn.Module):
def __init__(self, input_features, state_size):
super(LLTM, self).__init__()
self.input_features = input_features
self.state_size = state_size
self.weights = torch.nn.Parameter(
torch.empty(3 * state_size, input_features + state_size))
self.bias = torch.nn.Parameter(torch.empty(3 * state_size))
self.reset_parameters()
def reset_parameters(self):
stdv = 1.0 / math.sqrt(self.state_size)
for weight in self.parameters():
weight.data.uniform_(-stdv, +stdv)
def forward(self, input, state):
return LLTMFunction.apply(input, self.weights, self.bias, *state)
性能比较
既然我们能够从PyTorch中使用和调用我们的C++代码，我们可以运行一个小型基准测试，看看通过用C++重写我们的操作获得了多少性能提升。我们将多次运行LLTM的前向和反向传播，并测量持续时间：
import time
import torch
batch_size = 16
input_features = 32
state_size = 128
X = torch.randn(batch_size, input_features)
h = torch.randn(batch_size, state_size)
C = torch.randn(batch_size, state_size)
rnn = LLTM(input_features, state_size)
forward = 0
backward = 0
for _ in range(100000):
start = time.time()
new_h, new_C = rnn(X, (h, C))
forward += time.time() - start
start = time.time()
(new_h.sum() + new_C.sum()).backward()
backward += time.time() - start
print('Forward: {:.3f} s | Backward {:.3f} s'.format(forward, backward))
如果我们用本文开头用纯Python编写的原始LLTM运行这段代码，我们会得到以下数字（在我的机器上）：
Forward: 506.480 us | Backward 444.694 us
以及我们的新C++版本：
Forward: 349.335 us | Backward 443.523 us
我们已经可以看到前向函数的速度显著提升（超过30%）。对于反向函数，虽然速度提升不明显，但也有所改善。我上面写的反向传递并没有特别优化，肯定还有改进的空间。此外，PyTorch的自动微分引擎可以自动并行化计算图，可能使用更高效的操作流程，并且是用C++实现的，因此预计会很快。尽管如此，这是一个良好的开端。
GPU设备上的性能
关于PyTorch的ATen后端的一个奇妙事实是，它抽象了你正在运行的计算设备。这意味着我们为CPU编写的相同代码也可以在GPU上运行，并且各个操作将相应地分派到GPU优化的实现。对于某些操作，如矩阵乘法（如mm或addmm），这是一个巨大的优势。让我们看看使用CUDA张量运行我们的C++代码能获得多少性能提升。我们的实现不需要任何更改，我们只需要将我们的张量放入GPU内存中，可以通过在创建时添加device=cuda_device参数或在创建后使用.to(cuda_device)来实现：
import torch
assert torch.cuda.is_available()
cuda_device = torch.device("cuda") # device object representing GPU
batch_size = 16
input_features = 32
state_size = 128
# Note the device=cuda_device arguments here
X = torch.randn(batch_size, input_features, device=cuda_device)
h = torch.randn(batch_size, state_size, device=cuda_device)
C = torch.randn(batch_size, state_size, device=cuda_device)
rnn = LLTM(input_features, state_size).to(cuda_device)
forward = 0
backward = 0
for _ in range(100000):
start = time.time()
new_h, new_C = rnn(X, (h, C))
torch.cuda.synchronize()
forward += time.time() - start
start = time.time()
(new_h.sum() + new_C.sum()).backward()
torch.cuda.synchronize()
backward += time.time() - start
print('Forward: {:.3f} us | Backward {:.3f} us'.format(forward * 1e6/1e5, backward * 1e6/1e5))
再次将我们的普通PyTorch代码与C++版本进行比较，现在两者都在CUDA设备上运行，我们再次看到了性能提升。对于Python/PyTorch：
Forward: 187.719 us | Backward 410.815 us
以及 C++/ATen：
Forward: 149.802 us | Backward 393.458 us
与非CUDA代码相比，这是一个巨大的整体加速。然而，通过编写自定义的CUDA内核，我们可以从C++代码中提取出更多的性能，我们很快就会深入探讨这一点。在此之前，让我们讨论另一种构建C++扩展的方法。
JIT 编译扩展
之前，我提到过有两种构建C++扩展的方法：使用setuptools或即时（JIT）编译。在介绍了前者之后，让我们详细讨论后者。JIT编译机制提供了一种通过调用PyTorch API中的一个简单函数torch.utils.cpp_extension.load()来即时编译和加载扩展的方式。对于LLTM，这看起来就像这样简单：
from torch.utils.cpp_extension import load
lltm_cpp = load(name="lltm_cpp", sources=["lltm.cpp"])
在这里，我们为函数提供与setuptools相同的信息。在后台，这将执行以下操作：
创建一个临时目录
/tmp/torch_extensions/lltm,将Ninja构建文件发送到该临时目录中，
将您的源文件编译成共享库，
将此共享库作为Python模块导入。
事实上，如果你将 verbose=True 传递给 cpp_extension.load()，你将会收到关于该过程的信息：
Using /tmp/torch_extensions as PyTorch extensions root...
Emitting ninja build file /tmp/torch_extensions/lltm_cpp/build.ninja...
Building extension module lltm_cpp...
Loading extension module lltm_cpp...
生成的Python模块将与setuptools生成的完全相同，
但消除了必须维护单独的setup.py构建文件的需求。如果你的设置更复杂，确实需要setuptools的全部功能，
你可以编写自己的setup.py——但在许多情况下，
这种JIT技术就足够了。第一次运行这行代码时，
会花费一些时间，因为扩展在后台编译。由于
我们使用Ninja构建系统来构建你的源代码，重新编译是
增量的，因此当你第二次运行Python模块时，
重新加载扩展是快速的，并且如果你没有更改扩展的
源文件，开销也很低。
编写混合C++/CUDA扩展
为了真正将我们的实现提升到一个新的水平，我们可以使用自定义的CUDA内核手动编写部分前向和后向传递。对于LLTM来说，这可能会特别有效，因为有许多按顺序进行的点操作，这些操作都可以在一个CUDA内核中融合和并行化。让我们看看如何编写这样的CUDA内核，并使用此扩展机制将其与PyTorch集成。
编写CUDA扩展的一般策略是首先编写一个C++文件，该文件定义了将从Python调用的函数，并使用pybind11将这些函数绑定到Python。此外，该文件还将声明在CUDA（.cu）文件中定义的函数。然后，C++函数将进行一些检查，并最终将其调用转发给CUDA函数。在CUDA文件中，我们编写实际的CUDA内核。cpp_extension包将负责使用C++编译器（如gcc）编译C++源文件，并使用NVIDIA的nvcc编译器编译CUDA源文件。这确保了每个编译器都负责编译它最熟悉的文件。最终，它们将被链接到一个共享库中，该库可以从Python代码中使用。
我们将从C++文件开始，例如，我们将其称为lltm_cuda.cpp：
#include <torch/extension.h>
#include <vector>
// CUDA forward declarations
std::vector<torch::Tensor> lltm_cuda_forward(
torch::Tensor input,
torch::Tensor weights,
torch::Tensor bias,
torch::Tensor old_h,
torch::Tensor old_cell);
std::vector<torch::Tensor> lltm_cuda_backward(
torch::Tensor grad_h,
torch::Tensor grad_cell,
torch::Tensor new_cell,
torch::Tensor input_gate,
torch::Tensor output_gate,
torch::Tensor candidate_cell,
torch::Tensor X,
torch::Tensor gate_weights,
torch::Tensor weights);
// C++ interface
#define CHECK_CUDA(x) TORCH_CHECK(x.device().is_cuda(), #x " must be a CUDA tensor")
#define CHECK_CONTIGUOUS(x) TORCH_CHECK(x.is_contiguous(), #x " must be contiguous")
#define CHECK_INPUT(x) CHECK_CUDA(x); CHECK_CONTIGUOUS(x)
std::vector<torch::Tensor> lltm_forward(
torch::Tensor input,
torch::Tensor weights,
torch::Tensor bias,
torch::Tensor old_h,
torch::Tensor old_cell) {
CHECK_INPUT(input);
CHECK_INPUT(weights);
CHECK_INPUT(bias);
CHECK_INPUT(old_h);
CHECK_INPUT(old_cell);
return lltm_cuda_forward(input, weights, bias, old_h, old_cell);
}
std::vector<torch::Tensor> lltm_backward(
torch::Tensor grad_h,
torch::Tensor grad_cell,
torch::Tensor new_cell,
torch::Tensor input_gate,
torch::Tensor output_gate,
torch::Tensor candidate_cell,
torch::Tensor X,
torch::Tensor gate_weights,
torch::Tensor weights) {
CHECK_INPUT(grad_h);
CHECK_INPUT(grad_cell);
CHECK_INPUT(input_gate);
CHECK_INPUT(output_gate);
CHECK_INPUT(candidate_cell);
CHECK_INPUT(X);
CHECK_INPUT(gate_weights);
CHECK_INPUT(weights);
return lltm_cuda_backward(
grad_h,
grad_cell,
new_cell,
input_gate,
output_gate,
candidate_cell,
X,
gate_weights,
weights);
}
PYBIND11_MODULE(TORCH_EXTENSION_NAME, m) {
m.def("forward", &lltm_forward, "LLTM forward (CUDA)");
m.def("backward", &lltm_backward, "LLTM backward (CUDA)");
}
正如你所见，它主要是样板代码、检查以及转发到我们将在CUDA文件中定义的函数。我们将这个文件命名为lltm_cuda_kernel.cu（注意.cu扩展名！）。NVCC可以合理地编译C++11，因此我们仍然可以使用ATen和C++标准库（但不能使用torch.h）。请注意，setuptools无法处理同名但扩展名不同的文件，因此如果你使用setup.py方法而不是JIT方法，你必须为你的CUDA文件取一个与C++文件不同的名称（对于JIT方法，lltm.cpp和lltm.cu可以正常工作）。让我们简单看一下这个文件的内容：
#include <torch/extension.h>
#include <cuda.h>
#include <cuda_runtime.h>
#include <vector>
template <typename scalar_t>
__device__ __forceinline__ scalar_t sigmoid(scalar_t z) {
return 1.0 / (1.0 + exp(-z));
}
在这里，我们看到我刚才描述的头部信息，以及我们正在使用CUDA特定的声明，如__device__和__forceinline__，以及像exp这样的函数。让我们继续介绍一些我们需要的辅助函数：
template <typename scalar_t>
__device__ __forceinline__ scalar_t d_sigmoid(scalar_t z) {
const auto s = sigmoid(z);
return (1.0 - s) * s;
}
template <typename scalar_t>
__device__ __forceinline__ scalar_t d_tanh(scalar_t z) {
const auto t = tanh(z);
return 1 - (t * t);
}
template <typename scalar_t>
__device__ __forceinline__ scalar_t elu(scalar_t z, scalar_t alpha = 1.0) {
return fmax(0.0, z) + fmin(0.0, alpha * (exp(z) - 1.0));
}
template <typename scalar_t>
__device__ __forceinline__ scalar_t d_elu(scalar_t z, scalar_t alpha = 1.0) {
const auto e = exp(z);
const auto d_relu = z < 0.0 ? 0.0 : 1.0;
return d_relu + (((alpha * (e - 1.0)) < 0.0) ? (alpha * e) : 0.0);
}
现在要实现一个函数，我们再次需要两件事：一个函数执行我们不希望手动明确编写的操作并调用CUDA内核，然后是我们想要加速的部分的实际CUDA内核。对于前向传递，第一个函数应该如下所示：
std::vector<torch::Tensor> lltm_cuda_forward(
torch::Tensor input,
torch::Tensor weights,
torch::Tensor bias,
torch::Tensor old_h,
torch::Tensor old_cell) {
auto X = torch::cat({old_h, input}, /*dim=*/1);
auto gates = torch::addmm(bias, X, weights.transpose(0, 1));
const auto batch_size = old_cell.size(0);
const auto state_size = old_cell.size(1);
auto new_h = torch::zeros_like(old_cell);
auto new_cell = torch::zeros_like(old_cell);
auto input_gate = torch::zeros_like(old_cell);
auto output_gate = torch::zeros_like(old_cell);
auto candidate_cell = torch::zeros_like(old_cell);
const int threads = 1024;
const dim3 blocks((state_size + threads - 1) / threads, batch_size);
AT_DISPATCH_FLOATING_TYPES(gates.type(), "lltm_forward_cuda", ([&] {
lltm_cuda_forward_kernel<scalar_t><<<blocks, threads>>>(
gates.data<scalar_t>(),
old_cell.data<scalar_t>(),
new_h.data<scalar_t>(),
new_cell.data<scalar_t>(),
input_gate.data<scalar_t>(),
output_gate.data<scalar_t>(),
candidate_cell.data<scalar_t>(),
state_size);
}));
return {new_h, new_cell, input_gate, output_gate, candidate_cell, X, gates};
}
这里的主要关注点是AT_DISPATCH_FLOATING_TYPES宏和内核启动（由<<<...>>>表示）。虽然ATen抽象了我们处理的张量的设备和数据类型，但在运行时，张量仍然由具体设备上的具体类型的内存支持。因此，我们需要一种方法在运行时确定张量的类型，然后选择性地调用具有相应正确类型签名的函数。如果手动完成，这（概念上）会看起来像这样：
switch (tensor.type().scalarType()) {
case torch::ScalarType::Double:
return function<double>(tensor.data<double>());
case torch::ScalarType::Float:
return function<float>(tensor.data<float>());
...
}
AT_DISPATCH_FLOATING_TYPES 的目的是为我们处理这种分发。它接受一个类型（在我们的例子中是 gates.type()）、一个名称（用于错误消息）和一个 lambda 函数。在这个 lambda 函数内部，类型别名 scalar_t 是可用的，并且被定义为在该上下文中张量在运行时的实际类型。因此，如果我们有一个模板函数（我们的 CUDA 内核将是这样的），我们可以使用这个 scalar_t 别名来实例化它，并且将调用正确的函数。在这种情况下，我们还希望将张量的数据指针作为该 scalar_t 类型的指针来检索。如果你想分发所有类型而不仅仅是浮点类型（Float 和 Double），你可以使用 AT_DISPATCH_ALL_TYPES。
请注意，我们使用普通的ATen执行一些操作。这些操作仍然会在GPU上运行，但使用的是ATen的默认实现。这是有意义的，因为ATen会使用高度优化的例程来处理诸如矩阵乘法（例如addmm）或卷积等操作，这些操作我们自己实现和改进会困难得多。
至于内核启动本身，我们在这里指定每个CUDA块将有1024个线程，并且整个GPU网格被分成尽可能多的1 x 1024线程块，以填充我们的矩阵，每个组件一个线程。例如，如果我们的状态大小为2048，批量大小为4，我们将启动总共4 x 2 = 8个块，每个块有1024个线程。如果你以前从未听说过CUDA“块”或“网格”，关于CUDA的入门阅读可能会有所帮助。
实际的CUDA内核相当简单（如果你以前编程过GPU）：
template <typename scalar_t>
__global__ void lltm_cuda_forward_kernel(
const scalar_t* __restrict__ gates,
const scalar_t* __restrict__ old_cell,
scalar_t* __restrict__ new_h,
scalar_t* __restrict__ new_cell,
scalar_t* __restrict__ input_gate,
scalar_t* __restrict__ output_gate,
scalar_t* __restrict__ candidate_cell,
size_t state_size) {
const int column = blockIdx.x * blockDim.x + threadIdx.x;
const int index = blockIdx.y * state_size + column;
const int gates_row = blockIdx.y * (state_size * 3);
if (column < state_size) {
input_gate[index] = sigmoid(gates[gates_row + column]);
output_gate[index] = sigmoid(gates[gates_row + state_size + column]);
candidate_cell[index] = elu(gates[gates_row + 2 * state_size + column]);
new_cell[index] =
old_cell[index] + candidate_cell[index] * input_gate[index];
new_h[index] = tanh(new_cell[index]) * output_gate[index];
}
}
这里主要有趣的是，我们能够完全并行地计算所有这些逐点操作，针对我们门矩阵中的每个单独组件。如果你想象必须用一个巨大的for循环在串行中处理一百万个元素，你可以明白为什么这会快得多。
使用访问器
你可以在CUDA内核中看到，我们直接使用正确类型的指针进行操作。实际上，在CUDA内核中直接使用高级类型无关的张量会非常低效。
然而，这以易用性和可读性为代价，特别是对于高维数据。在我们的例子中，我们知道例如连续的gates张量有3个维度：
批次，大小为
batch_size，步幅为3*state_size行，大小为
3和步幅为state_size索引，大小为
state_size和步幅为1
那么我们如何在内核中访问元素 gates[n][row][column] 呢？
事实证明，你需要通过一些简单的算术来使用步幅访问你的元素。
gates.data<scalar_t>()[n*3*state_size + row*state_size + column]
除了冗长之外，这个表达式需要明确知道步幅，因此需要将其作为参数传递给内核函数。你可以看到，在接受具有不同大小的多个张量的内核函数的情况下，你最终会得到一个非常长的参数列表。
幸运的是，ATen 提供了访问器，这些访问器通过一次动态检查创建，以确保张量是特定类型和维度的。然后，访问器暴露了一个 API，用于高效地访问张量元素，而无需转换为单个指针：
torch::Tensor foo = torch::rand({12, 12});
// assert foo is 2-dimensional and holds floats.
auto foo_a = foo.accessor<float,2>();
float trace = 0;
for(int i = 0; i < foo_a.size(0); i++) {
// use the accessor foo_a to get tensor data.
trace += foo_a[i][i];
}
访问器对象具有相对高级的接口，包括.size()和
.stride()方法以及多维索引。.accessor<>
接口旨在高效访问CPU张量上的数据。对于CUDA张量，等效的是
packed_accessor64<>和packed_accessor32<>，它们
生成具有64位或32位整数索引的打包访问器。
与Accessor的根本区别在于，Packed Accessor在其结构内部复制大小和步幅数据，而不是指向它。这使我们能够将其传递给CUDA内核函数并在其中使用其接口。
我们可以设计一个函数，它接受Packed Accessors而不是指针。
__global__ void lltm_cuda_forward_kernel(
const torch::PackedTensorAccessor32<scalar_t,3,torch::RestrictPtrTraits> gates,
const torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> old_cell,
torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> new_h,
torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> new_cell,
torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> input_gate,
torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> output_gate,
torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> candidate_cell)
让我们分解这里使用的模板。前两个参数 scalar_t 和
2 与常规的 Accessor 相同。参数
torch::RestrictPtrTraits 表示必须使用 __restrict__ 关键字。还要注意，我们使用了 PackedAccessor32 变体，它将大小和步长存储在 int32_t 中。这很重要，因为使用 64 位变体 (PackedAccessor64) 可能会使内核变慢。
函数声明变为
template <typename scalar_t>
__global__ void lltm_cuda_forward_kernel(
const torch::PackedTensorAccessor32<scalar_t,3,torch::RestrictPtrTraits> gates,
const torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> old_cell,
torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> new_h,
torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> new_cell,
torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> input_gate,
torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> output_gate,
torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> candidate_cell) {
//batch index
const int n = blockIdx.y;
// column index
const int c = blockIdx.x * blockDim.x + threadIdx.x;
if (c < gates.size(2)){
input_gate[n][c] = sigmoid(gates[n][0][c]);
output_gate[n][c] = sigmoid(gates[n][1][c]);
candidate_cell[n][c] = elu(gates[n][2][c]);
new_cell[n][c] =
old_cell[n][c] + candidate_cell[n][c] * input_gate[n][c];
new_h[n][c] = tanh(new_cell[n][c]) * output_gate[n][c];
}
}
实现更加易读！然后通过在主机函数中使用.packed_accessor32<>方法创建Packed Accessors来调用此函数。
std::vector<torch::Tensor> lltm_cuda_forward(
torch::Tensor input,
torch::Tensor weights,
torch::Tensor bias,
torch::Tensor old_h,
torch::Tensor old_cell) {
auto X = torch::cat({old_h, input}, /*dim=*/1);
auto gate_weights = torch::addmm(bias, X, weights.transpose(0, 1));
const auto batch_size = old_cell.size(0);
const auto state_size = old_cell.size(1);
auto gates = gate_weights.reshape({batch_size, 3, state_size});
auto new_h = torch::zeros_like(old_cell);
auto new_cell = torch::zeros_like(old_cell);
auto input_gate = torch::zeros_like(old_cell);
auto output_gate = torch::zeros_like(old_cell);
auto candidate_cell = torch::zeros_like(old_cell);
const int threads = 1024;
const dim3 blocks((state_size + threads - 1) / threads, batch_size);
AT_DISPATCH_FLOATING_TYPES(gates.type(), "lltm_forward_cuda", ([&] {
lltm_cuda_forward_kernel<scalar_t><<<blocks, threads>>>(
gates.packed_accessor32<scalar_t,3,torch::RestrictPtrTraits>(),
old_cell.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
new_h.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
new_cell.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
input_gate.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
output_gate.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
candidate_cell.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>());
}));
return {new_h, new_cell, input_gate, output_gate, candidate_cell, X, gates};
}
反向传播遵循几乎相同的模式，我不会进一步详细阐述：
template <typename scalar_t>
__global__ void lltm_cuda_backward_kernel(
torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> d_old_cell,
torch::PackedTensorAccessor32<scalar_t,3,torch::RestrictPtrTraits> d_gates,
const torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> grad_h,
const torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> grad_cell,
const torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> new_cell,
const torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> input_gate,
const torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> output_gate,
const torch::PackedTensorAccessor32<scalar_t,2,torch::RestrictPtrTraits> candidate_cell,
const torch::PackedTensorAccessor32<scalar_t,3,torch::RestrictPtrTraits> gate_weights) {
//batch index
const int n = blockIdx.y;
// column index
const int c = blockIdx.x * blockDim.x + threadIdx.x;
if (c < d_gates.size(2)){
const auto d_output_gate = tanh(new_cell[n][c]) * grad_h[n][c];
const auto d_tanh_new_cell = output_gate[n][c] * grad_h[n][c];
const auto d_new_cell =
d_tanh(new_cell[n][c]) * d_tanh_new_cell + grad_cell[n][c];
d_old_cell[n][c] = d_new_cell;
const auto d_candidate_cell = input_gate[n][c] * d_new_cell;
const auto d_input_gate = candidate_cell[n][c] * d_new_cell;
d_gates[n][0][c] =
d_input_gate * d_sigmoid(gate_weights[n][0][c]);
d_gates[n][1][c] =
d_output_gate * d_sigmoid(gate_weights[n][1][c]);
d_gates[n][2][c] =
d_candidate_cell * d_elu(gate_weights[n][2][c]);
}
}
std::vector<torch::Tensor> lltm_cuda_backward(
torch::Tensor grad_h,
torch::Tensor grad_cell,
torch::Tensor new_cell,
torch::Tensor input_gate,
torch::Tensor output_gate,
torch::Tensor candidate_cell,
torch::Tensor X,
torch::Tensor gates,
torch::Tensor weights) {
auto d_old_cell = torch::zeros_like(new_cell);
auto d_gates = torch::zeros_like(gates);
const auto batch_size = new_cell.size(0);
const auto state_size = new_cell.size(1);
const int threads = 1024;
const dim3 blocks((state_size + threads - 1) / threads, batch_size);
AT_DISPATCH_FLOATING_TYPES(X.type(), "lltm_backward_cuda", ([&] {
lltm_cuda_backward_kernel<scalar_t><<<blocks, threads>>>(
d_old_cell.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
d_gates.packed_accessor32<scalar_t,3,torch::RestrictPtrTraits>(),
grad_h.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
grad_cell.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
new_cell.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
input_gate.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
output_gate.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
candidate_cell.packed_accessor32<scalar_t,2,torch::RestrictPtrTraits>(),
gates.packed_accessor32<scalar_t,3,torch::RestrictPtrTraits>());
}));
auto d_gate_weights = d_gates.reshape({batch_size, 3*state_size});
auto d_weights = d_gate_weights.t().mm(X);
auto d_bias = d_gate_weights.sum(/*dim=*/0, /*keepdim=*/true);
auto d_X = d_gate_weights.mm(weights);
auto d_old_h = d_X.slice(/*dim=*/1, 0, state_size);
auto d_input = d_X.slice(/*dim=*/1, state_size);
return {d_old_h, d_input, d_weights, d_bias, d_old_cell, d_gates};
}
将C++/CUDA操作与PyTorch集成
将我们支持CUDA的操作与PyTorch集成再次非常简单。
如果你想编写一个setup.py脚本，它可能看起来像这样：
from setuptools import setup
from torch.utils.cpp_extension import BuildExtension, CUDAExtension
setup(
name='lltm',
ext_modules=[
CUDAExtension('lltm_cuda', [
'lltm_cuda.cpp',
'lltm_cuda_kernel.cu',
])
],
cmdclass={
'build_ext': BuildExtension
})
现在我们使用CUDAExtension()而不是CppExtension()。我们可以直接指定.cu文件以及.cpp文件——库会为你处理所有相关的麻烦。JIT机制甚至更简单：
from torch.utils.cpp_extension import load
lltm = load(name='lltm', sources=['lltm_cuda.cpp', 'lltm_cuda_kernel.cu'])
